@echo off
chcp 65001 >nul
echo ========================================
echo   灵枢智能任务平台 - Windows 一键部署
echo ========================================

:: 检查 Docker 是否可用
docker version >nul 2>&1
if errorlevel 1 (
    echo.
    echo [错误] 未检测到 Docker 或 Docker Desktop 未启动！
    echo 请先：
    echo   1. 安装 Docker Desktop：https://www.docker.com/products/docker-desktop/
    echo   2. 确保切换到 Linux 容器模式（右键任务栏 Docker 图标）
    echo   3. 等待 Docker 图标变绿后重新运行本脚本
    pause
    exit /b 1
)

echo.
echo [1/3] 导入 Docker 镜像（首次约需 1-3 分钟）...
docker load -i "%~dp0mysql_8.0.tar.gz"
if errorlevel 1 ( echo [错误] mysql 镜像导入失败 & pause & exit /b 1 )
docker load -i "%~dp0lingshu_app.tar.gz"
if errorlevel 1 ( echo [错误] lingshu_app 镜像导入失败 & pause & exit /b 1 )

echo.
echo [2/3] 解压项目代码...
tar -xzf "%~dp0lingshu_code.tar.gz" -C "%~dp0"
if errorlevel 1 ( echo [错误] 解压代码失败 & pause & exit /b 1 )

echo.
echo [3/3] 启动服务...
cd /d "%~dp0lingshu"
docker compose up -d
if errorlevel 1 ( echo [错误] 服务启动失败，请运行 docker logs lingshu_app 查看详情 & pause & exit /b 1 )

echo.
echo ========================================
echo   部署完成！
echo   浏览器访问：http://localhost:5000
echo   默认账号：admin / admin123
echo ========================================
pause