infer_clone/infer/src/IR/Mangled.re

/*
 * vim: set ft=rust:
 * vim: set ft=reason:
 *
 * Copyright (c) 2009 - 2013 Monoidics ltd.
 * Copyright (c) 2013 - present Facebook, Inc.
 * All rights reserved.
 *
 * This source code is licensed under the BSD style license found in the
 * LICENSE file in the root directory of this source tree. An additional grant
 * of patent rights can be found in the PATENTS file in the same directory.
 */
open! IStd;


/** Module for Mangled Names */
let module F = Format;

type t = {plain: string, mangled: option string} [@@deriving compare];

let equal pn1 pn2 => compare pn1 pn2 == 0;


/** Convert a string to a mangled name */
let from_string (s: string) => {plain: s, mangled: None};


/** Create a mangled name from a plain and mangled string */
let mangled (plain: string) (mangled: string) => {
  plain,
  mangled: Some (plain ^ "{" ^ mangled ^ "}")
};


/** Convert a mangled name to a string */
let to_string (pn: t) => pn.plain;


/** Convert a full mangled name to a string */
let to_string_full (pn: t) =>
  switch pn.mangled {
  | Some mangled => pn.plain ^ "{" ^ mangled ^ "}"
  | None => pn.plain
  };


/** Get mangled string if given */
let get_mangled pn =>
  switch pn.mangled {
  | Some s => s
  | None => pn.plain
  };


/** Create a mangled type name from a package name and a class name */
let from_package_class package_name class_name =>
  if (package_name == "") {
    from_string class_name
  } else {
    from_string (package_name ^ "." ^ class_name)
  };


/** Pretty print a mangled name */
let pp f pn => F.fprintf f "%s" (to_string pn);

let module MangledSet = Caml.Set.Make {
  type nonrec t = t;
  let compare = compare;
};